Del is using Aw-Radw to collect the radiation data and also to repeatedly 
trigger a batch file that generates the graphs and uses FTP to transfer 
the graphs to the website.

A reply to Del's E-Mail:

Del,

Aw-Graph with Aw-Gif.Exe will not work unless the screen is in full-screen 
mode.

You could use Aw-Radw to make the gifs as mentioned before but also use 
the -p and the -v switches. See Aw-Radw wordpad help file for info. about 
the -p and the -v command-line switches.

Another method, instead of making a gif file one can have aw-graph make a 
bmp graphics file, using the -T switch then use Aw-Radw to make a gif file 
from the bmp file.  This can be done in minimized state.

For example the following batch file made the graphs seen here: 
http://www.aw-el.com/umdnj_old/index.htm
and takes four arguments namely %1 = radfile %2 = dir to move gifs to %3 = 
calb %4= first part of gif name i.e. Rad1

Start of batch file:
rem @echo off
setlocal
set TitleTag=UMDNJ RadPC1 RM-60
set XaxisTag=Date-Time (East Coast US)

set pixx=583
set pixy=182
set calb=%3

CD \make_gif
copy %1 nf.rad
rem changsec nf.rad 3600

rem make the day radiation binary file nd.rad from the full data set file nf.rad
del se-1.rad
start /SHARED /B /WAIT /MIN section -m1440 nf.rad
del nd.rad
ren se-1.rad nd.rad

rem make the week radiation binary file nw.rad from the full data set file nf.rad
rem in case it didn't rename it, del it
del se-1.rad
start /SHARED /B /WAIT /MIN section -m10080 nf.rad
del nw.rad
ren se-1.rad nw.rad

rem Make the day gif file nday.gif
rem 2 min and 15 min ave. assuming 10 sec. TBU

set Curve1Tag=2 min. average
set Curve2Tag=15 min. average
set Compress1=12
set Compress2=90

set AW_KEY=DC1%Curve1Tag%`2%Curve2Tag%`AXT%TitleTag%`X%XaxisTag%`ASAD~~~
start /SHARED /B /WAIT /MIN aw-graph -X60 -p%pixx% %pixy% -T -C%calb% -Dnd.rad`%COMPRESS1%,nd.rad`%COMPRESS2% -K@

start /B /WAIT /MIN aw-radw -Iawg.bmp -Gnday.gif

rem Make the week gif file nweek.gif
rem 2 min and 15 min ave.
set AW_KEY=DC1%Curve1Tag%`2%Curve2Tag%`AXT%TitleTag%`X%XaxisTag%`ASAD~~~
start /SHARED /B /WAIT /MIN aw-graph -X60 -p%pixx% %pixy% -T -C%calb% -Dnw.rad`%COMPRESS1%,nw.rad`%COMPRESS2% -K@

start /B /WAIT /MIN aw-radw -Iawg.bmp -Gnweek.gif

rem 15 min and 2 hr ave.
set Curve1Tag=Full Data Set
set Curve2Tag=2 hr. average
set Compress1=90
set Compress2=720

set AW_KEY=DC1%Curve1Tag%`2%Curve2Tag%`AXT%TitleTag%`X%XaxisTag%`ASAD~~~
start /SHARED /B /WAIT /MIN aw-graph -X60 -p%pixx% %pixy% -T -C%calb% -Dnf.rad`%COMPRESS1%,nf.rad`%COMPRESS2% -K@

start /B /WAIT /MIN aw-radw -Iawg.bmp -Gall.gif
start /SHARED /B /WAIT /MIN gifmake -s
rem cls
move nday.gif %2\%4day.gif
move nweek.gif %2\%4week.gif
move newall.gif %2\%4all.gif
exit

Best Regards / Bryan