Using Aware Electronics Radiation Monitors and Software


A method to auto generate graphs using Aware Electronics Monitors and Windows software package Aw-Radw under 64 bit Windows.

See bottom of this page for real time graphs made by-way-of the following information.
Instructions below involve copying and pasting to batch files. When copying from an http file like this one, sometimes every line copied and pasted will have an extra space character at the end of the line which would disrupt the batch file execution. To avoid this, copy from the batch files found in this zip file (save zip to PC then unzip it:
db_make_graphs.zip

Note the db_make_graphs.zip contains a batch file named SETUP_DB.BAT. Assuming all your Aw-Radw files are in folder \AWARE, you could download the zip, unzip it to the same disk drive where you want to make the folders. etc., then run SETUP_DB.BAT which will make the folders mentioned below, and copy the default batch files and needed other files to the folders, at-which-point you could skip the following instructions that deal with making the folders, making the three batch files START_RAD_DATA.BAT, DB_BMP.BAT and DB_MAKE_GRAPHS.BAT and copying the files. You could then right-click then edit the three batch files, in-turn, to make any changes. You would still need to make the shortcuts, setup Aw-Radw and make the doftp.bat batch file as detailed below.


64 bit Windows will run Aw-Radw.Exe directly but 64 bit Windows does not include the ability to run 16 bit programs like Aw-Graph.Exe and Section.Exe. Therefore the following method uses the included program AW-DB.EXE which will run 16 bit programs under 64 bit Windows. Note that commands for AW-DB.EXE require short path-filenames.

Method to auto generate gif image graphs of radiation data, assuming Aware Electronics Programs are in C:\AWARE and the binary radiation data files will be stored in C:\RAD_DATA and the graph images will be stored in C:\RAD_DATA\GRAPHS.

(You can use Windows Explorer to create new folders, copy files, create shortcuts etc. Start Windows Explorer by clicking: Windows "Start" button - "All Programs" - "Accessories" - "Windows Explorer")

1. Use Windows Explorer to make a folder on the PC named C:\RAD_DATA and a folder named C:\RAD_DATA\BACKUP

2. In Windows Explorer click on RAD_DATA to change to that folder.

3. Click right mouse button then "New" - "Shortcut" then enter C:\AWARE\AW-RADW.EXE then type in for name "AW-RADW Shortcut" then click "Finish".

4. In Windows Explorer right click the shortcut "AW-RADW Shortcut" then click "Properties" then change "Start in:" to C:\RAD_DATA then click "OK"

5. Copy C:\AWARE\AW-RADW.SET to C:\RAD_DATA

6. Click the shortcut made in steps 3 and 4.

7. Aw-Radw starts. Click Aw-Radw menu item "Rad Options" and if need be, set all the various options, for example RM COM Port, Calibration Factor, and set the TBU to sixty seconds. Set "Rad Options" - "Default Message" to anything you want for example "My Office Location". If you plan to also generate ASCII files, set the Aw-Radw menu items under "Output Options" - "ASCII File Output Options". (See Aw-Radw help file).

Click Aw-Radw's "Exit" then "Quit Program" and Aw-Radw will then store all the menu item variables you set in C:\RAD_DATA\AW-RADW.SET then exit.

8. In Windows Explorer, with RAD_DATA as the current folder, click right mouse button then "New" - "Shortcut" then enter:

C:\AWARE\AW-DB.EXE -e -c "mount C C:\AWARE" -c "mount D C:\RAD_DATA" -c "D:" -c "C:\AW-GRAPH.EXE"

then type in for name "AW-GRAPH (aw-db)" then click "Finish".

9. In Windows Explorer right click the shortcut "AW-GRAPH (aw-db)" then click "Properties" then "Program" then change "Working:" to C:\RAD_DATA then click "OK"

10. Copy C:\AWARE\AW-GRAPH.SET to C:\RAD_DATA

11. Click the shortcut made in steps 8 and 9.

12. Aw-Graph starts. Use keyboard arrow keys to select Aw-Graph menu item "Make Graph"(then enter key) then "Aperture Size"(enter key) then replace what is there with 0 (zero) then enter key. Use arrow keys to select Aw-Graph menu item "Quit"(enter) then "Yes"(enter) then Aw-Graph asks "Save Setup" and select "Yes"(enter) and Aw-Graph exits saving the setup variables in the C:\RAD_DATA\AW-GRAPH.SET file. (Note you can use the Aw-Graph shortcut as above to change any of the other Aw-Graph variables, for example background colors, line colors, line styles, etc.).

13. In Windows Explorer, with C:\RAD_DATA as the current folder, right click the white area then click "New" then "Text Document" then rename it to "START_RAD_DATA.BAT".

14. Right click "START_RAD_DATA.BAT" then "Edit" then Windows Notepad starts.

15. Paste the following into the Notepad window:

@echo off
REM Batch file "START_RAD_DATA.BAT" for Startup Menu
setlocal
title Starting Aw-Radw

REM ***Add the location of the Aware programs to the path variable
set PATH=C:\AWARE;%PATH%

REM ************* JOIN THE CURRENT RAD FILE TO THE MASTER RAD FILE *****************************
if not exist ALLDATA.RAD copy backup\ALLDATA.RAD ALLDATA.RAD
REM *** sleep a little in case OS needs time to copy
w-sleep 2
if not exist ALLDATA.RAD copy CURRENT.RAD ALLDATA.RAD
w-sleep 2
if exist TEMP.RAD (
del TEMP.RAD
w-sleep 2
)
if not exist ALLDATA.RAD goto START_COLLECT
rename ALLDATA.RAD TEMP.RAD
w-sleep 2
start /SHARED /B /WAIT /MIN JOIN-RAD CURRENT.RAD TEMP.RAD ALLDATA.RAD
REM *** if JOIN-RAD reported an error, don't save a backup copy of ALLDATA.RAD
if errorlevel 1 goto START_COLLECT
copy ALLDATA.RAD BACKUP\ALLDATA.RAD
:START_COLLECT
if exist CURRENT.RAD del CURRENT.RAD
REM *** sleep a little in case OS needs time to delete
w-sleep 2

REM ************* Start Aw-Radw saving binary data to C:\RAD_DATA\CURRENT.RAD
start /min AW-RADW -LCURRENT.RAD -S

REM *** to start AW-RADW as above but also save the data to an ASCII file named C:\RAD_DATA\RAD_ASCII.TXT, use:
REM *** start /min AW-RADW -LCURRENT.RAD -aRAD_ASCII.TXT -S
REM *** Note for ASCII files, make sure you set Aw-Radw's menu items under "Output Options" - "ASCII Text File Options"

REM End of Batch file for Startup Menu

16. Save the above text in NotePad to C:\RAD_DATA\START_RAD_DATA.BAT

17. In Windows Explore, right click START_RAD_DATA.BAT then "Create Shortcut".

18. Right click the shortcut made in step 17 then "Copy".

19. Click Windows "Start" button, "All Programs" then right click "Startup" then "Explorer" then "Edit" then "Paste" which pastes the shortcut to C:\RAD_DATA\START_RAD_DATA.BAT in the Startup folder.

Now when Windows reboots for any reason, for example a power outage, when it starts again, Windows will automatically start Aw-Radw as per the C:\RAD_DATA\START_RAD_DATA.BAT batch file.

********End of info for startup menu

********Start of info to create the graphs We will make two batch files and we are assuming Aware Electronics Programs are in C:\AWARE and the binary radiation data files will be stored in C:\RAD_DATA and the graph images will be stored in C:\RAD_DATA\GRAPHS. We are also assuming you know now how to use Windows Explorer and Windows NotePad as above:

First copy the following files to the C:\RAD_DATA folder:
Copy C:\AWARE\dosbox.conf to C:\RAD_DATA
Copy C:\AWARE\AWDIPBMP.BGI to C:\RAD_DATA
Copy C:\AWARE\EGAVGA.BGI to C:\RAD_DATA
Copy C:\AWARE\AWLT.CHR to C:\RAD_DATA

********Make DB_BMP.BAT

1. Create the folder C:\RAD_DATA\GRAPHS

2. Create a new file DB_BMP.BAT in the C:\RAD_DATA folder.

3. Place (copy-paste) the following to the file DB_BMP.BAT and then save the file:

@echo off
REM ************* SET CONFIGURATION VARIABLES *******************************************
set TitleTag=My Radiation Data in Office
set XaxisTag=Date-Time (East Coast US)
REM
REM ***Set Y-axis Label and calb. for microR/hr standardized to Cesium 137
REM ***Note microR/hr calb for RM-60 is 105, calb for RM-70 is 149. calb for RM-80 is 354, calb for RM-G90 is 960
REM ***Also note the character will display as the micro character
set YaxisTag=RM-60 R/hr`
set calb=105
REM
REM ***Set Y-axis Label and calb. for microSv/hr standardized to Cesium 137
REM ***Note Sv/hr calb for RM-60 is 10500, calb for RM-70 is 14900. calb for RM-80 is 35400, calb for RM-G90 is 96000
REM set YaxisTag=RM-60 Sv/hr`
REM set calb=10500
REM
REM ***Set Y-axis Label and calb. for Counts per unit time. For example if TBU is 60 secs. then calb=0 displays CPM
REM set YaxisTag=RM-60 CPM`
REM set calb=0
REM
REM *** To have the Y-axis label equal the Y-Axis Caption entered when starting Aw-Radw collection of the rad. data,
REM *** enter a blank as in:
REM set YaxisTag=
REM
REM *** The size of the graph in x and y pixels:
set pixx=800
set pixy=400
REM ***Switch to D: drive which is really C:\RAD_DATA
D:
REM ****************************************** 6 HOUR GRAPH ************************************
DEL D:\SE-1.RAD
C:\SECTION -M360 D:\ALLDATA.RAD
del 6-hr.rad
ren SE-1.RAD 6-hr.rad
set COMPRESS1=1
set COMPRESS2=15
set Curve1Tag=1 min. average
set Curve2Tag=15 min. average
set AW_KEY=DC1%Curve1Tag%`2%Curve2Tag%`AXT%TitleTag% - PAST 6 HOURS`X%XaxisTag%`Y%YaxisTag%ARAY``D~~~
C:\aw-graph.exe -X100 -C%calb% -p%pixx% %pixy% -T -DD:\6-hr.rad`%COMPRESS1%,D:\6-hr.rad`%COMPRESS2% -k@
del 6-hr.rad
del 6-hr.bmp
ren awg.bmp 6-hr.bmp
REM ****************************************** 1 DAY GRAPH ************************************
DEL D:\SE-1.RAD
C:\SECTION -M1440 D:\ALLDATA.RAD
del 24-hr.rad
ren SE-1.RAD 24-hr.rad
set COMPRESS1=5
set COMPRESS2=60
set Curve1Tag=5 min. average
set Curve2Tag=60 min. average
set AW_KEY=DC1%Curve1Tag%`2%Curve2Tag%`AXT%TitleTag% - PAST 24 HOURS`X%XaxisTag%`Y%YaxisTag%ARAY``D~~~
C:\aw-graph.exe -X100 -C%calb% -p%pixx% %pixy% -T -DD:\24-hr.rad`%COMPRESS1%,D:\24-hr.rad`%COMPRESS2% -k@
del 24-hr.rad
del 24-hr.bmp
ren awg.bmp 24-hr.bmp
REM ****************************************** 7 DAY GRAPH ************************************
DEL D:\SE-1.RAD
C:\SECTION -M10080 D:\ALLDATA.RAD
del 7-day.rad
ren SE-1.RAD 7-day.rad
set COMPRESS1=15
set COMPRESS2=180
set Curve1Tag=15 min. average
set Curve2Tag=3 hour average
set AW_KEY=DC1%Curve1Tag%`2%Curve2Tag%`AXT%TitleTag% - PAST 7 DAYS`X%XaxisTag%`Y%YaxisTag%ARAY``D~~~
C:\aw-graph.exe -X100 -C%calb% -p%pixx% %pixy% -T -DD:\7-day.rad`%COMPRESS1%,D:\7-day.rad`%COMPRESS2% -k@
del 7-day.rad
del 7-day.bmp
ren awg.bmp 7-day.bmp
REM **************************************** 28 DAY GRAPH *******************************************
DEL D:\SE-1.RAD
C:\SECTION -M40320 D:\ALLDATA.RAD
del 28-day.rad
ren SE-1.RAD 28-day.rad
set COMPRESS1=60
set COMPRESS2=360
set Curve1Tag=1 hour average
set Curve2Tag=6 hour average
set AW_KEY=DC1%Curve1Tag%`2%Curve2Tag%`AXT%TitleTag% - PAST 28 DAYS`X%XaxisTag%`Y%YaxisTag%ARAY``D~~~
C:\aw-graph.exe -X100 -C%calb% -p%pixx% %pixy% -T -DD:\28-day.rad`%COMPRESS1%,D:\28-day.rad`%COMPRESS2% -k@
del 28-day.rad
del 28-day.bmp
ren awg.bmp 28-day.bmp
REM **************************************** 365 day GRAPH *******************************************
DEL D:\SE-1.RAD
C:\SECTION -M525600 D:\ALLDATA.RAD
del 365-day.rad
ren SE-1.RAD 365-day.rad
set COMPRESS1=240
set COMPRESS2=1440
set Curve1Tag=4 hour average
set Curve2Tag=1 day average
set AW_KEY=DC1%Curve1Tag%`2%Curve2Tag%`AXT%TitleTag% - PAST 365 DAYS`X%XaxisTag%`Y%YaxisTag%ARAY``D~~~
C:\aw-graph.exe -X100 -C%calb% -p%pixx% %pixy% -T -DD:\365-day.rad`%COMPRESS1%,D:\365-day.rad`%COMPRESS2% -k@
del 365-day.rad
del 365-day.bmp
ren awg.bmp 365-day.bmp
exit
REM *****End of DB_BMP.BAT

Save the DB_BMP.BAT file in the C:\RAD_DATA folder

Now to create DB_MAKE_GRAPHS.BAT which Aw-Radw will trigger:

1. Create a new file DB_MAKE_GRAPHS.BAT in the C:\RAD_DATA folder.

2. Place (copy-paste) the following to the file DB_MAKE_GRAPHS.BAT and then save the file:

@echo off
setlocal
title Making Graphs
REM ***Add the location of the Aware programs to the path variable for this batch file
set PATH=C:\AWARE;%PATH%
REM ***Set location for program files
set PROG_DIR=C:\AWARE
REM ***Set location for rad files
set RAD_DIR=C:\RAD_DATA
REM ***Set location for graph files
set GRAPH_DIR=C:\RAD_DATA\GRAPHS
REM
REM ************* JOIN THE CURRENT RAD FILE TO THE MASTER RAD FILE *****************************
if not exist ALLDATA.RAD copy backup\ALLDATA.RAD ALLDATA.RAD
REM *** sleep a little in case OS needs time to copy
w-sleep 2
if not exist ALLDATA.RAD copy CURRENT.RAD ALLDATA.RAD
w-sleep 2
if exist TEMP.RAD (
del TEMP.RAD
w-sleep 2
)
REM *** if no ALLDATA.RAD then exit. We'll make it next time through
if not exist ALLDATA.RAD (
exit
)
rename ALLDATA.RAD TEMP.RAD
w-sleep 2
start /SHARED /B /WAIT /MIN JOIN-RAD CURRENT.RAD TEMP.RAD ALLDATA.RAD
REM *** if JOIN-RAD reported an error then exit. We'll try it again next time through
if errorlevel 1 (
exit
)
copy ALLDATA.RAD BACKUP\ALLDATA.RAD
REM ***********Start aw-db.exe such that C: = PROG_DIR (C:\aware); D: = RAD_DIR (C:\RAD_DATA); E: = GRAPH_DIR (C:\RAD_DATA\GRAPHS)
REM ***********and tell it to run DB_BMP.BAT batch file
start /SHARED /B /WAIT aw-db -e -m -c "mount C %PROG_DIR%" -c "mount D %RAD_DIR%" -c "mount E %GRAPH_DIR%" -c "D:\DB_BMP.BAT"
REM
REM We should now have five bitmap files named 6-hr.bmp, 24-hr.bmp, 7-day.bmp, 28-day.bmp and 365-day.bmp
REM
REM ***********Convert the bitmap files to gif files***********
del %GRAPH_DIR%\6-hr.gif
start /B /WAIT /MIN aw-radw.exe -I6-hr.bmp -G%GRAPH_DIR%\6-HR.GIF
del 6-hr.bmp
del %GRAPH_DIR%\24-hr.gif
start /B /WAIT /MIN aw-radw.exe -I24-hr.bmp -G%GRAPH_DIR%\24-HR.GIF
del C:\RAD_DATA\24-hr.bmp
del %GRAPH_DIR%\7-day.gif
start /B /WAIT /MIN aw-radw.exe -I7-day.bmp -G%GRAPH_DIR%\7-DAY.GIF
del C:\RAD_DATA\7-day.bmp
del %GRAPH_DIR%\28-day.gif
start /B /WAIT /MIN aw-radw.exe -I28-day.bmp -G%GRAPH_DIR%\28-DAY.GIF
del C:\RAD_DATA\28-day.bmp
del %GRAPH_DIR%\365-day.gif
start /B /WAIT /MIN aw-radw.exe -I365-day.bmp -G%GRAPH_DIR%\365-DAY.GIF
del C:\RAD_DATA\365-day.bmp
del se-1.rad
REM ****************************************Change to the graphs folder and call doftp.bat
cd %GRAPH_DIR%
call doftp.bat
exit
REM ***************End of DB_MAKE_GRAPHS.BAT**********************************************************

********Start of info to ftp the graphs to a website

Notice the last part of the above DB_MAKE_GRAPHS.BAT file changes to the folder C:\RAD_DATA\GRAPHS (i.e. %GRAPH_DIR%) and then calls the batch file doftp.bat. There are many ways to auto ftp files to a website. Next we will create doftp.bat containing windows commands to ftp the files:

1. Create a new file doftp.bat in the C:\RAD_DATA\GRAPHS folder

2. Place (copy-paste) the following to the file C:\RAD_DATA\GRAPHS\doftp.bat and then save the file:

ftp -i -s:ftplist.txt
if errorlevel 1 ftp -i -s:ftplist.txt

3. Save the file C:\RAD_DATA\GRAPHS\doftp.bat

4. Create a new file ftplist.txt in the C:\RAD_DATA\GRAPHS folder

5. Place (copy-paste) the following to the file C:\RAD_DATA\GRAPHS\ftplist.txt and then save the file:

open mywebsite.com
username
password
binary
put C:\RAD_DATA\GRAPHS\6-hr.gif 6-hr.gif
put C:\RAD_DATA\GRAPHS\24-hr.gif 24-hr.gif
put C:\RAD_DATA\GRAPHS\7-day.gif 7-day.gif
put C:\RAD_DATA\GRAPHS\28-day.gif 28-day.gif
put C:\RAD_DATA\GRAPHS\365-day.gif 365-day.gif
bye

Replace the above mywebsite.com with your website's ftp server name which most often is the website address without the www.

Replace username with your ftp username which most often is along the lines of username.mywebsite.com

Replace password with your ftp password.

**********Setting Aw-Radw to run the MAKE_GRAPHS.BAT file

1. From Windows Explorer, in the C:\RAD_DATA folder, click on the shortcut you made to start Aw-Radw.

2. Click Aw-Radw menu "Output Options" - "Trigger a Program Every X Points" - "Trigger Program Yes-No" -"Trigger Program Minimized".

3. Click Aw-Radw menu "Output Options" - "Trigger a Program Every X Points" - "Choose Trigger Program" and enter DB_MAKE_GRAPHS.BAT

4. Click Aw-Radw menu "Output Options" - "Trigger a Program Every X Points" - "Commandline Argument for Trigger Program" and erase anything there.

5. Click Aw-Radw menu "Output Options" - "Trigger a Program Every X Points" - "Choose # of Points per Trigger" and enter 10.

6. Exit Aw-Radw.

That's it. To test your setup and start collecting, click the C:\RAD_DATA\START_RAD_DATA.BAT or the shortcut link you made in the Startup folder and Aw-Radw should startup, collecting the rad data to CURRENT.RAD and every ten minutes it will trigger the DO_MAKE_GRAPHS.BAT file.

Note: The program JOIN-RAD.EXE should be in your C:\AWARE folder. It might be in a zip file within C:\AWARE i.e. C\AWARE\join-rad.zip in-which-case use Windows Explorer to click on C\AWARE\join-rad.zip, right click join-rad.exe then Copy then paste it to C:\AWARE.


Note about AW-DB.EXE:

AW-DB.EXE is the program that runs the 16 bit programs Aw-Graph.exe and Section.Exe under 64 bit Windows. When AW-DB.EXE starts, with C:\RAD_DATA as the default folder, it first looks for a file named C:\RAD_DATA\dosbox.conf. The file dosbox.conf tells AW-DB.EXE how to set various operating parameters. If one finds the graphics file generation is too slow, one can edit the dosbox.conf file with Window's Notepad. Find the line:

cycles=fixed 32768

and increase the number as in:

cycles=fixed 65536

which might cut in half the time used to generate the graphs. On some machines, a lower number might be faster. The higher the number, the more CPU time will be used by AW-DB.EXE so adjusting the number might be a process of trial and error.


Actual Real-Time Graphs Using Above Technique

6 Hour Graph

Radon Fleas in Basement


24 Hour Graph

Radon Fleas in Basement


7 Day Graph

Radon Fleas in Basement


28 Day Graph

Radon Fleas in Basement


365 Day Graph

Radon Fleas in Basement


E-mail aware@aw-el.com
Phone:(800)729-5397 or Phone/Fax: (302)655-3800